VBA：【Selenium×Edge】ブラウザのドライバ(webdriver、edgedriver)のバージョンチェックと自動更新用VBAコード

by chasou_tech · 公開済み 2022年6月17日 · 更新済み 2023年8月25日

「Selenium」を導入しようとして、ブラウザのドライバのバージョン関連で困った点。

ドライバが頻繁にアップデートされるので、都度バージョンエラーで動かなくなる。

会社のブラウザのバージョンが管理されていて、古いものである場合が多い。

ユーザが使うPCによってドライバのバージョンが異なる場合がある。

これらをユーザの手を煩わせずに解決しようと思って、ブラウザのドライバ(edgedriver)とSelenium Basicのドライバのバージョンを比較して、異なるバージョンの場合は上書きするようなVBAを作成しました。

◆Edge版

Edgeでの依頼だったので、ひとまずEdgeで動作するように作っています。
エラー処理などは入れていないので、使う際にはエラー処理や条件など追加して使ってください。
動作確認：Access2013、Access2016、Office365のAccess、Excel 2016

導入方法(Accessの場合)

下記の画像のように設定して実行することで自動更新が行われます。
①フォームのボタンを作成し「その他」→「名前」を「実行」とする。
②「イベント」タブ→「クリック時」を「イベントプロシージャ」にする。

導入方法(Excelの場合)

①「マクロの登録」から「実行_Click」を呼び出す。
②VBAの「★」部分をExcelのものにする。

VBA

Option Explicit

'Windows APIの宣言'
    Private Declare PtrSafe Function URLDownloadToFile _
        Lib "urlmon" Alias "URLDownloadToFileA" _
        (ByVal pCaller As Long, _
        ByVal szURL As String, _
        ByVal szFileName As String, _
        ByVal dwReserved As Long, _
        ByVal lpfnCB As Long) As Long
'#######################################################'
'フォームのボタン押下時'
Public Sub 実行_Click()
    If MsgBox("実行します。", vbYesNo) = vbYes Then
        'Yesの場合、バージョンのチェックと更新を実行します。'
        Call chkEdgeVersion
    Else
        MsgBox "実行を中止しました。"
    End If
    
End Sub

'#######################################################'
'チェックと更新プログラムのMain部分'
Public Sub chkEdgeVersion()
    Dim BrowserVer As String
    Dim thisDriverVer As String
    Dim xTmpPath As String
    Dim DownloadFileName As String
    Dim SeleniumDriverPath As String
    Dim uName As String
    
    xTmpPath = CurrentProject.Path & "\xTmp"'Access用'
    'xTmpPath = ThisWorkbook.Path & "\xTmp"'★'←Excelの場合はこちらに変更'
    DownloadFileName = xTmpPath & "\edgedriver_win64.zip"
    '保存先をデフォルトから変更している方は変更してください。'
    uName = Environ("USERNAME")
    SeleniumDriverPath = "C:\Users\" & uName & "\AppData\Local\SeleniumBasic\edgedriver.exe"
    '"
    'フォルダの有無の確認。なければフォルダを作成する'
    If Dir(xTmpPath, vbDirectory) = "" Then
        MkDir xTmpPath
    End If
    
    '①PCのブラウザのバージョンをチェック'
    BrowserVer = chkBrowserVer

    '②Seleniumで保存しているドライバのバージョンチェック'
    If Dir(SeleniumDriverPath) = "" Then
        'ない場合はチェックせず、新しいファイルを書き込む'
    Else
        thisDriverVer = chkDriverVer(SeleniumDriverPath)
    End If

    If BrowserVer <> thisDriverVer Then
        '③ブラウザバージョンと一致したドライバのダウンロード'
        Call DriverDownload(BrowserVer, DownloadFileName)
        
        '④ダウンロードしたファイルを解凍して所定の場所にドライバを保存'
        Call DriverUpdate(DownloadFileName, xTmpPath, SeleniumDriverPath)
    Else
        MsgBox "バージョン一致" '何もしない'
    End If

    MsgBox "完了"

End Sub
'#######################################################'
'//①【Edge】ブラウザのバージョンチェックします'
Function chkBrowserVer() As String
    Dim chkVer As String

    'Edgeの場合'
    chkVer = "HKEY_CURRENT_USER\SOFTWARE\Microsoft\Edge\BLBeacon\version"
    chkBrowserVer = CreateObject("WScript.Shell").RegRead(chkVer)
    
End Function
'#######################################################'
'//②現在SeleniumBasicフォルダに保存されているドライバのバージョンをチェックします'
Function chkDriverVer(SeleniumDriverPath As String) As String
    Dim FSO As Object

    Set FSO = CreateObject("Scripting.FileSystemObject")
    
    chkDriverVer = FSO.GetFileVersion(FileName:=SeleniumDriverPath)

End Function
'#######################################################'
'//③ドライバをダウンロードします'
Public Sub DriverDownload(BrowserVer As String, dFileName As String)
   
    Dim dURL As String
    Dim dResult As String
    
    'ダウンロードするファイルのURL'
    dURL = "https://msedgedriver.azureedge.net/" & BrowserVer & "/edgedriver_win64.zip"
    
    'ダウンロード'
    dResult = URLDownloadToFile(0, dURL, dFileName, 0, 0)

End Sub
'#######################################################'
'//④ドライバを解凍して特定の場所に保存します。'
Public Sub DriverUpdate(DownloadFileName As String, xTmpPath As String, SeleniumDriverPath As String)

    Dim psCommand As String
    Dim wsh As Object
    Dim dResult As String

    '//実行するPowerShellのコマンド作成。「 -Force」で上書き。'
    psCommand = "powershell -NoProfile -ExecutionPolicy Unrestricted Expand-Archive -Path " & DownloadFileName & " -DestinationPath " & xTmpPath & " -Force"

    Set wsh = CreateObject("WScript.Shell")
    
    '//PowerShellのコマンド実行'
    '指定した場所に解凍されます。'
    dResult = wsh.Run(Command:=psCommand, WindowStyle:=0, WaitOnReturn:=True)
    
    '解凍したexeファイルをSeleniumのドライバに上書き'
    FileCopy xTmpPath & "\msedgedriver.exe", SeleniumDriverPath
    
    Set wsh = Nothing

End Sub

100

101

102

103

104

105

106

107

108

109

110

111

112

113

114

115

116

117

118

119

120

121

122

123

124

Option Explicit

'Windows APIの宣言'

Private Declare PtrSafe Function URLDownloadToFile _

Lib "urlmon" Alias "URLDownloadToFileA" _

(ByVal pCaller As Long, _

ByVal szURL As String, _

ByVal szFileName As String, _

ByVal dwReserved As Long, _

ByVal lpfnCB As Long) As Long

'#######################################################'

'フォームのボタン押下時'

Public Sub 実行_Click()

If MsgBox("実行します。", vbYesNo) = vbYes Then

'Yesの場合、バージョンのチェックと更新を実行します。'

Call chkEdgeVersion

Else

MsgBox "実行を中止しました。"

End If

End Sub

'#######################################################'

'チェックと更新プログラムのMain部分'

Public Sub chkEdgeVersion()

Dim BrowserVer As String

Dim thisDriverVer As String

Dim xTmpPath As String

Dim DownloadFileName As String

Dim SeleniumDriverPath As String

Dim uName As String

xTmpPath = CurrentProject.Path & "\xTmp"'Access用'

'xTmpPath = ThisWorkbook.Path & "\xTmp"'★'←Excelの場合はこちらに変更'

DownloadFileName = xTmpPath & "\edgedriver_win64.zip"

'保存先をデフォルトから変更している方は変更してください。'

uName = Environ("USERNAME")

SeleniumDriverPath = "C:\Users\" & uName & "\AppData\Local\SeleniumBasic\edgedriver.exe"

'フォルダの有無の確認。なければフォルダを作成する'

If Dir(xTmpPath, vbDirectory) = "" Then

MkDir xTmpPath

End If

'①PCのブラウザのバージョンをチェック'

BrowserVer = chkBrowserVer

'②Seleniumで保存しているドライバのバージョンチェック'

If Dir(SeleniumDriverPath) = "" Then

'ない場合はチェックせず、新しいファイルを書き込む'

Else

thisDriverVer = chkDriverVer(SeleniumDriverPath)

End If

If BrowserVer <> thisDriverVer Then

'③ブラウザバージョンと一致したドライバのダウンロード'

Call DriverDownload(BrowserVer, DownloadFileName)

'④ダウンロードしたファイルを解凍して所定の場所にドライバを保存'

Call DriverUpdate(DownloadFileName, xTmpPath, SeleniumDriverPath)

Else

MsgBox "バージョン一致" '何もしない'

End If

MsgBox "完了"

End Sub

'#######################################################'

'//①【Edge】ブラウザのバージョンチェックします'

Function chkBrowserVer() As String

Dim chkVer As String

'Edgeの場合'

chkVer = "HKEY_CURRENT_USER\SOFTWARE\Microsoft\Edge\BLBeacon\version"

chkBrowserVer = CreateObject("WScript.Shell").RegRead(chkVer)

End Function

'#######################################################'

'//②現在SeleniumBasicフォルダに保存されているドライバのバージョンをチェックします'

Function chkDriverVer(SeleniumDriverPath As String) As String

Dim FSO As Object

Set FSO = CreateObject("Scripting.FileSystemObject")

chkDriverVer = FSO.GetFileVersion(FileName:=SeleniumDriverPath)

End Function

'#######################################################'

'//③ドライバをダウンロードします'

Public Sub DriverDownload(BrowserVer As String, dFileName As String)

Dim dURL As String

Dim dResult As String

'ダウンロードするファイルのURL'

dURL = "https://msedgedriver.azureedge.net/" & BrowserVer & "/edgedriver_win64.zip"

'ダウンロード'

dResult = URLDownloadToFile(0, dURL, dFileName, 0, 0)

End Sub

'#######################################################'

'//④ドライバを解凍して特定の場所に保存します。'

Public Sub DriverUpdate(DownloadFileName As String, xTmpPath As String, SeleniumDriverPath As String)

Dim psCommand As String

Dim wsh As Object

Dim dResult As String

'//実行するPowerShellのコマンド作成。「 -Force」で上書き。'

psCommand = "powershell -NoProfile -ExecutionPolicy Unrestricted Expand-Archive -Path " & DownloadFileName & " -DestinationPath " & xTmpPath & " -Force"

Set wsh = CreateObject("WScript.Shell")

'//PowerShellのコマンド実行'

'指定した場所に解凍されます。'

dResult = wsh.Run(Command:=psCommand, WindowStyle:=0, WaitOnReturn:=True)

'解凍したexeファイルをSeleniumのドライバに上書き'

FileCopy xTmpPath & "\msedgedriver.exe", SeleniumDriverPath

Set wsh = Nothing

End Sub

◆Egde版

VBA：【Selenium×Chrome】ブラウザのドライバ（WebDriver、chromedriver）のバージョンチェックと自動更新

投稿: 2022年6月22日

【VBA×Selenium】Chrome：ブラウザのドライバ（WebDriver・chromedriver）とSelenium Basicのブラウザのドライバのバージョンを比較して、異なるバージョンの場合は上書きする方法について